home *** CD-ROM | disk | FTP | other *** search
/ Aminet 44 / Aminet 44 (2001)(GTI - Schatztruhe)[!][Aug 2001].iso / Aminet / misc / math / YACAS.lha / share / yacas / trigsimp.ys < prev    next >
Text File  |  2001-05-24  |  10KB  |  432 lines
  1.  
  2. /* This file defines TrigSimpCombine. TrigSimpCombine is designed to
  3.    simplify expressions like Cos(a)*Sin(b) to additions
  4.    only (in effect, removing multiplications between
  5.    trigonometric functions).
  6.  
  7.    The accepted expressions allow additions and multiplications
  8.    between trig. functions, and raising trig. functions to an
  9.    integer power.
  10.  
  11.    You can invoke it by calling TrigSimpCombine(f). Examples:
  12.     TrigSimpCombine(Cos(a)*Sin(a^2+b)^2)
  13.     TrigSimpCombine(Cos(a)*Sin(a)^2)
  14.     TrigSimpCombine(Cos(a)^3*Sin(a)^2)
  15.     TrigSimpCombine(d*Cos(a)^3*Sin(a)^2)
  16.     TrigSimpCombine(Cos(a)^3*Sin(a)^2)
  17.     TrigSimpCombine(Cos(a)*Sin(a))
  18.     TrigSimpCombine(Cos(a)*Sin(b)*Cos(c))
  19.    
  20.  */
  21.  
  22.  
  23. /* FSin, FCos and :*: are used for the internal representation
  24.    of the expression to work on:
  25.    - a*b -> a:*:b   this is used because we want to expand powers,
  26.      without the standard engine collapsing them back again.
  27.    - a*Sin(b) -> FSin(a,b) and a*Cos(b) -> FCos(a,b). This makes
  28.      adding and multiplying expressions with trig. functions, non-trig.
  29.      functions, constants, etc. a lot easier.
  30. */
  31. RuleBase("FSin",{f,x});
  32. RuleBase("FCos",{f,x});
  33. RuleBase(":*:",{x,y});
  34. Infix(":*:",3);
  35.  
  36.  
  37. IsTrig(f) := (Type(f) = "Sin" Or Type(f) = "Cos");
  38. IsFTrig(f) := (Type(f) = "FSin" Or Type(f) = "FCos");
  39. IsMul(f) := (Type(f) = "*");
  40. IsMulF(f) := (Type(f) = ":*:");
  41.  
  42. IsPow(f):=
  43.   (Type(f) = "^" And
  44.    IsInteger(f[2]) And
  45.    f[2] > 1
  46.   );
  47.  
  48.  
  49. /* Convert Sin/Cos to FSin/FCos */
  50. RuleBase("TrigChange",{f});
  51. Rule("TrigChange",1,1,Type(f)="Cos") FCos(1,f[1]);
  52. Rule("TrigChange",1,1,Type(f)="Sin") FSin(1,f[1]);
  53.  
  54. /* Do a full replacement to internal format on a term. */
  55. RuleBase("FReplace",{f});
  56. UnFence("FReplace",1);
  57. Rule("FReplace",1,1,IsMul(f))  Substitute(f[1]) :*: Substitute(f[2]);
  58. Rule("FReplace",1,2,IsPow(f))  (Substitute(f[1]) :*: Substitute(f[1])) :*: Substitute(f[1]^(f[2]-2));
  59. Rule("FReplace",1,3,IsTrig(f)) TrigChange(f);
  60. FTest(f):=(IsMul(f) Or IsPow(f) Or IsTrig(f));
  61.  
  62. /* Central function that converts to internal format */
  63. FToInternal(f):=Substitute(f,"FTest","FReplace");
  64.  
  65. FReplaceBack(f):=(Substitute(f[1])*Substitute(f[2]));
  66. UnFence("FReplaceBack",1);
  67. FFromInternal(f):=Substitute(f,"IsMulF","FReplaceBack");
  68.  
  69.  
  70. /* FLog(s,f):=[WriteString(s:" ");Write(f);NewLine();]; */
  71.  FLog(s,f):=[]; 
  72.  
  73.  
  74. /* FSimpTerm simplifies the current term, wrt. trigonometric functions. */
  75. RuleBase("FSimpTerm",{f,rlist});
  76. UnFence("FSimpTerm",2);
  77.  
  78. /* Addition: add all the subterms */
  79. Rule("FSimpTerm",2,1,Type(f) = "+")
  80. [
  81.   Local(result,lst);
  82.   lst:=Flatten(f,"+");
  83.  
  84.   result:={{},{}};
  85. FLog("simpadd",lst);
  86.  
  87.   ForEach(tt,lst)
  88.   [
  89.     Local(new);
  90.     new:=FSimpTerm(tt,{{},{}});
  91.     result:={Concat(result[1],new[1]),Concat(result[2],new[2])};
  92.   ];
  93.   result;
  94. ];
  95.  
  96.  
  97. TrigNegate(f):=
  98. [
  99.   UnList({f[0],-(f[1]),f[2]});
  100. ];
  101.  
  102. Rule("FSimpTerm",2,1,Type(f) = "-" And NrArgs(f)=1)
  103. [
  104.   Local(result);
  105.   result:=FSimpTerm(f[1],{{},{}});
  106.   Substitute(result,"IsFTrig","TrigNegate");
  107. ];
  108. Rule("FSimpTerm",2,1,Type(f) = "-" And NrArgs(f)=2)
  109. [
  110.   Local(result1,result2);
  111.   result1:=FSimpTerm(f[1],{{},{}});
  112.   result2:=FSimpTerm(-(f[2]),{{},{}});
  113.   {Concat(result1[1],result2[1]),Concat(result1[2],result2[2])};
  114. ];
  115.  
  116. Rule("FSimpTerm",2,2,Type(f) = ":*:")
  117. [
  118.   FSimpFactor({Flatten(f,":*:")});
  119. ];
  120. Rule("FSimpTerm",2,3,Type(f) = "FSin")
  121. [
  122.   {rlist[1],f:(rlist[2])};
  123. ];
  124. Rule("FSimpTerm",2,3,Type(f) = "FCos")
  125. [
  126.   {f:(rlist[1]),rlist[2]};
  127. ];
  128.  
  129. Rule("FSimpTerm",2,4,True)
  130. [
  131.   {(FCos(f,0)):(rlist[1]),rlist[2]};
  132. ];
  133.  
  134. /* FSimpFactor does the difficult part. it gets a list, representing
  135.    factors, a*b*c -> {{a,b,c}}, and has to add terms from it.
  136.    Special cases to deal with:
  137.    - (a+b)*c -> a*c+b*c -> {{a,c},{b,c}}
  138.    - {a,b,c} where one of them is not a trig function or an addition:
  139.      replace with FCos(b,0), which is b*Cos(0) = b
  140.    - otherwise, combine two factors and make them into an addition.
  141.    - the lists should get shorter, but the number of lists should
  142.      get longer, until there are only single terms to be added.
  143.  */
  144. FSimpFactor(flist):=
  145. [
  146.   Local(rlist);
  147.   rlist:={{},{}};
  148.   /* Loop over each term */
  149.   While(flist != {})
  150.   [
  151.     Local(term);
  152. FLog("simpfact",flist);
  153.     term:=Head(flist);
  154.     flist:=Tail(flist);
  155.     FProcessTerm(term);
  156.   ];
  157. FLog("simpfact",flist);
  158.  
  159. FLog("rlist",rlist);
  160.   rlist;
  161. ];
  162. UnFence("FSimpFactor",1);
  163.  
  164.  
  165. RuleBase("FProcessTerm",{t});
  166. UnFence("FProcessTerm",1);
  167.  
  168. /* Deal with (a+b)*c -> a*c+b*c */
  169. Rule("FProcessTerm",1,1,Type(t[1]) = "+")
  170. [
  171.   Local(split,term1,term2);
  172.   split:=t[1];
  173.   term1:=FlatCopy(t);
  174.   term2:=FlatCopy(t);
  175.   term1[1]:=split[1];
  176.   term2[1]:=split[2];
  177.   DestructiveInsert(flist,1,term1);
  178.   DestructiveInsert(flist,1,term2);
  179. ];
  180. Rule("FProcessTerm",1,1,Type(t[1]) = "-" And NrArgs(t[1]) = 2)
  181. [
  182.   Local(split,term1,term2);
  183.   split:=t[1];
  184.   term1:=FlatCopy(t);
  185.   term2:=FlatCopy(t);
  186.   term1[1]:=split[1];
  187.   term2[1]:=split[2];
  188.   DestructiveInsert(term2,1,FCos(-1,0));
  189.   DestructiveInsert(flist,1,term1);
  190.   DestructiveInsert(flist,1,term2);
  191. ];
  192.  
  193. Rule("FProcessTerm",1,1,Length(t)>1 And Type(t[2]) = "-" And NrArgs(t[2]) = 2)
  194. [
  195.   Local(split,term1,term2);
  196.   split:=t[2];
  197.   term1:=FlatCopy(t);
  198.   term2:=FlatCopy(t);
  199.   term1[2]:=split[1];
  200.   term2[2]:=split[2];
  201.   DestructiveInsert(term2,1,FCos(-1,0));
  202.   DestructiveInsert(flist,1,term1);
  203.   DestructiveInsert(flist,1,term2);
  204. ];
  205.  
  206. Rule("FProcessTerm",1,1,Type(t[1]) = ":*:")
  207. [
  208.   Local(split,term);
  209.   split:=t[1];
  210.   term:=FlatCopy(t);
  211.   term[1]:=split[1];
  212.   DestructiveInsert(term,1,split[2]);
  213.   DestructiveInsert(flist,1,term);
  214. ];
  215.  
  216. Rule("FProcessTerm",1,1,Length(t)>1 And Type(t[2]) = ":*:")
  217. [
  218.   Local(split,term);
  219.   split:=t[2];
  220.   term:=FlatCopy(t);
  221.   term[2]:=split[1];
  222.   DestructiveInsert(term,1,split[2]);
  223.   DestructiveInsert(flist,1,term);
  224. ];
  225.  
  226. Rule("FProcessTerm",1,1,Type(t[1]) = "-" And NrArgs(t[1]) = 1)
  227. [
  228.   Local(split,term);
  229.   split:=t[1];
  230.   term:=FlatCopy(t);
  231.   term[1]:=split[1];
  232.   DestructiveInsert(term,1,FCos(-1,0));
  233.   DestructiveInsert(flist,1,term);
  234. ];
  235. Rule("FProcessTerm",1,1,Length(t)>1 And Type(t[2]) = "-" And NrArgs(t[2]) = 1)
  236. [
  237.   Local(split,term);
  238.   split:=t[2];
  239.   term:=FlatCopy(t);
  240.   term[2]:=split[1];
  241.   DestructiveInsert(term,1,FCos(-1,0));
  242.   DestructiveInsert(flist,1,term);
  243. ];
  244.  
  245.  
  246. /* Deal with (a*(b+c) -> a*b+a*c */
  247. Rule("FProcessTerm",1,1,Length(t)>1 And Type(t[2]) = "+")
  248. [
  249.   Local(split,term1,term2);
  250.   split:=t[2];
  251.   term1:=FlatCopy(t);
  252.   term2:=FlatCopy(t);
  253.   term1[2]:=split[1];
  254.   term2[2]:=split[2];
  255.   DestructiveInsert(flist,1,term1);
  256.   DestructiveInsert(flist,1,term2);
  257. ];
  258.  
  259.  
  260.  
  261. /* Deal with a*FCos(1,b) ->FCos(a,0)*FCos(1,b) */
  262. Rule("FProcessTerm",1,2,Not(IsFTrig(t[1])) )
  263. [
  264.   t[1]:=FCos(t[1],0);
  265.   DestructiveInsert(flist,1,t);
  266. ];
  267. Rule("FProcessTerm",1,2,Length(t)>1 And Not(IsFTrig(t[2])) )
  268. [
  269.   t[2]:=FCos(t[2],0);
  270.   DestructiveInsert(flist,1,t);
  271. ];
  272.  
  273.  
  274. Rule("FProcessTerm",1,4,Length(t)=1 And Type(t[1]) = "FCos") 
  275. [
  276.   DestructiveInsert(rlist[1],1,t[1]);
  277. ];
  278. Rule("FProcessTerm",1,4,Length(t)=1 And Type(t[1]) = "FSin") 
  279. [
  280.   DestructiveInsert(rlist[2],1,t[1]);
  281. ];
  282.  
  283. /* Now deal with the real meat: FSin*FCos etc. Reduce the multiplication
  284.    of the first two terms to an addition, adding two new terms to
  285.    the pipe line.
  286.  */
  287. Rule("FProcessTerm",1,5,Length(t)>1)
  288. [
  289.   Local(x,y,term1,term2,news);
  290.   x:=t[1];
  291.   y:=t[2];
  292.   news:=TrigSimpCombineB(x,y);
  293.   /* Drop one term */
  294.   t:=Tail(t);
  295.   term1:=FlatCopy(t);
  296.   term2:=FlatCopy(t);
  297.   term1[1]:=news[1];
  298.   term2[1]:=news[2];
  299.   DestructiveInsert(flist,1,term1);
  300.   DestructiveInsert(flist,1,term2);
  301. ];
  302.  
  303. /* TrigSimpCombineB : take two FSin/FCos factors, and write them out into two terms */
  304. RuleBase("TrigSimpCombineB",{x,y});
  305. Rule("TrigSimpCombineB",2,1,Type(x) = "FCos" And Type(y) = "FCos")
  306.      { FCos((x[1]*y[1])/2,x[2]+y[2]) , FCos((x[1]*y[1])/2,x[2]-y[2]) };
  307. Rule("TrigSimpCombineB",2,1,Type(x) = "FSin" And Type(y) = "FSin")
  308.      { FCos(-(x[1]*y[1])/2,x[2]+y[2]) , FCos((x[1]*y[1])/2,x[2]-y[2]) };
  309. Rule("TrigSimpCombineB",2,1,Type(x) = "FSin" And Type(y) = "FCos")
  310.      { FSin((x[1]*y[1])/2,x[2]+y[2]) , FSin( (x[1]*y[1])/2,x[2]-y[2]) };
  311. Rule("TrigSimpCombineB",2,1,Type(x) = "FCos" And Type(y) = "FSin")
  312.      { FSin((x[1]*y[1])/2,x[2]+y[2]) , FSin(-(x[1]*y[1])/2,x[2]-y[2]) };
  313.  
  314.  
  315. RuleBase("TrigSimpCombine",{f});
  316. Rule("TrigSimpCombine",1,1,IsList(f))
  317.   Map("TrigSimpCombine",{f});
  318.  
  319. Rule("TrigSimpCombine",1,10,True)
  320. [
  321.   Local(new,varlist);
  322.   new:=f;
  323.  
  324.   /* varlist is used for normalizing the trig. arguments */
  325.   varlist:=VarList(f);
  326.   
  327. /* Convert to internal format. */
  328.   new:=FToInternal(new);
  329. FLog("Internal",new);
  330.  
  331.   /* terms will contain FSin/FCos entries, the final result */
  332.  
  333.   /* rlist gathers the true final result */
  334.   Local(terms);
  335.   terms:=FSimpTerm(new,{{},{}});
  336.   /* terms now contains two lists: terms[1] is the list of cosines,
  337.      and terms[2] the list of sines.
  338.    */
  339. FLog("terms",terms);
  340.  
  341.   /* cassoc and sassoc will contain the assoc lists with the cos/sin
  342.      arguments as key.
  343.    */
  344.   Local(cassoc,sassoc);
  345.   cassoc:={};
  346.   sassoc:={};
  347.   ForEach(item,terms[1])
  348.   [
  349.     CosAdd(item);
  350.   ];
  351.   ForEach(item,terms[2])
  352.   [
  353.     SinAdd(item);
  354.   ];
  355. FLog("cassoc",cassoc);
  356. FLog("sassoc",sassoc);
  357.  
  358.   /* Now rebuild the normal form */
  359.   Local(result);
  360.   result:=0;
  361.   ForEach(item,cassoc)
  362.   [
  363. Log("item",item);
  364.     result:=result+Expand(item[2])*Cos(item[1]);
  365.   ];
  366.   ForEach(item,sassoc)
  367.   [
  368. Log("item",item);
  369.     result:=result+Expand(item[2])*Sin(item[1]);
  370.   ];
  371.  
  372.   result;
  373. ];
  374.  
  375.  
  376.  
  377. CosAdd(t):=
  378. [
  379.   Local(look,arg);
  380.   arg:=Expand(t[2],varlist);
  381.   look:=Assoc(arg,cassoc);
  382.   If(look = Empty,
  383.      [
  384.        arg:=Expand(-arg,varlist);
  385.        look:=Assoc(arg,cassoc); 
  386.        If(look = Empty,
  387.          DestructiveInsert(cassoc,1,{arg,t[1]}),
  388.          look[2]:=look[2]+t[1]
  389.          );
  390.      ]
  391.      ,
  392.      look[2]:=look[2]+t[1]
  393.     );
  394. ];
  395. UnFence("CosAdd",1);
  396.  
  397. SinAdd(t):=
  398. [
  399.   Local(look,arg);
  400.   arg:=Expand(t[2],varlist);
  401.   look:=Assoc(arg,sassoc);
  402.   If(look = Empty,
  403.      [
  404.        arg:=Expand(-arg,varlist);
  405.        look:=Assoc(arg,sassoc);
  406.        If(look = Empty,
  407.          DestructiveInsert(sassoc,1,{arg,-(t[1])}),
  408.      look[2]:=look[2]-(t[1])
  409.          );
  410.      ]
  411.      ,
  412.      look[2]:=look[2]+t[1]
  413.     );
  414. ];
  415. UnFence("SinAdd",1);
  416.  
  417.  
  418. /*
  419. In( 4 ) = Exp(I*a)*Exp(I*a)      
  420. Out( 4 ) = Complex(Cos(a)^2-Sin(a)^2,Cos(a)*Sin(a)+Sin(a)*Cos(a));
  421. In( 5 ) = Exp(I*a)*Exp(-I*a)     
  422. Out( 5 ) = Complex(Cos(a)^2+Sin(a)^2,Sin(a)*Cos(a)-Cos(a)*Sin(a));
  423.  
  424. In( 5 ) = Exp(I*a)*Exp(I*b) 
  425. Out( 5 ) = Complex(Cos(a)*Cos(b)-Sin(a)*Sin(b),Cos(a)*Sin(b)+Sin(a)*Cos(b));
  426. In( 6 ) = Exp(I*a)*Exp(-I*b) 
  427. Out( 6 ) = Complex(Cos(a)*Cos(b)+Sin(a)*Sin(b),Sin(a)*Cos(b)-Cos(a)*Sin(b));
  428.  
  429.  
  430. */
  431.  
  432.